How to backup your Arturia user presets the easy way (Windows only)

[pedu]

Hi guys

I have written a Windows batch script that will create a backup of your user presets (script attached). It will create a backup file named user_presets.rar in your Presets folder (default %ProgramData%\Arturia\Presets\user_presets.rar)

Note! You need WinRAR installed or at least the commandline version rar.exe somewhere on your system. However I recommend the installaion of WinRAR for easier/visual extraction from the backup file

Code: [Select]

@echo off

setlocal enabledelayedexpansion

set "PRESETS=%ProgramData%\Arturia\Presets"
set "RAR=%ProgramFiles%\WinRAR\rar.exe"
set "PARMS=a -ep2 -m1 -ma5 -qo+ -isnd"
set "ARCHIVE=%PRESETS%\user_presets.rar"

set /a x=0
for /f "tokens=*" %%s in ('dir /b /s /a:d "%PRESETS%\User"') do (
set "str=%%s"
if [!str:~-9!]==[User\User] (
set dirs[!x!]=%%s
set /a x+=1
)
)
set /a x-=1

if not defined dirs[0] goto:DONE

FOR /L %%n IN (0,1,%x%) DO (
"%RAR%" %PARMS% "%ARCHIVE%" "!dirs[%%n]!\*"
echo:
echo:
)

:DONE
endlocal
echo:All done
timeout 10

You may have to change the following two lines to suit your needs

Code: [Select]

set "PRESETS=%ProgramData%\Arturia\Presets"
set "RAR=%ProgramFiles%\WinRAR\rar.exe"

Note! The backup file will contain every user preset ever being backed up. Even though you may have deleted some of them in the meantime. To avoid this behavior change the script like this

Code: [Select]

if not defined dirs[0] goto:DONE
to

Code: [Select]

if not defined dirs[0] goto:DONE
del /q /f "%ARCHIVE%"

By doing this the backup file will only contain current user presets. Like a snapshot of the user presets you have right now.

That's all folks. Hope you find it useful. I sure do.

Cheers,
Peter